AND()

¿Son todos ciertos?

Devuelve una Yes/No expresión, de la siguiente manera.

• TRUE si todas las condiciones son TRUE.
• FALSE si al menos una condición es FALSE.

Ejemplo de uso​

AND(FALSE, FALSE) devoluciones FALSE
AND(FALSE, TRUE) devoluciones FALSE
AND(TRUE, FALSE) devoluciones FALSE
AND(TRUE, TRUE) devoluciones TRUE
AND(ISNOTBLANK([Grade]), ([Grade] = "A")) devuelve TRUE sólo si el valor de la columna Grade está presente y tiene un valor exactamente A; en caso contrario, FALSE. Véase también: ISNOTBLANK()

AND(([Name] = "Acme"), ([Rating] > 3), [Preferred?]) devuelve TRUE solo si la fila es para la empresa nombrada Acme que tiene una calificación de 3 o superior y es un proveedor preferido; FALSEde lo contrario.

AND((LEN([_THIS]) > 3), CONTAINS([_THIS], "@")) devuelve TRUE si el valor de la columna actual (como con Valid_If) tiene al menos tres caracteres y contiene al menos un @símbolo.

Elegir los prospectos de venta más antiguos​

Elija filas en una tabla, tal vez con las funciones FILTER() o SELECT(), o por un segmento o filtro de seguridad, que describan los prospectos de ventas del usuario actual de la aplicación que desean ser contactados pero que no han sido contactados recientemente:

AND(
IN([Sales Contact], LIST(USEREMAIL(), "")),
NOT([DO NOT CALL]),
([Last Contact] < (TODAY() - 30))
)

• AND(..., ..., ...) requiere todas las condiciones deben ser TRUE.
• IN([Sales Contact], ...) coincide solo si el Sales Contact valor de la columna de la fila aparece en la lista construida.
• LIST(USEREMAIL(), "") construye una lista que contiene la dirección de correo electrónico del usuario de la aplicación actual y un valor en blanco, lo que permite que lo IN() anterior coincida con las filas con el usuario de la aplicación actual como el designado Sales Contacty las filas sin contacto designado.
• NOT([DO NOT CALL]) omite filas con un DO NOT CALL valor de columna de TRUE.
• [Last Contact] < (TODAY() - 30)coincide solo con filas con una Last Contactfecha de más de 30 días en el pasado.

Validar rango de fechas que no se superponen​

Valide el rango de fechas de una nueva fila y asegúrese de que no se superponga a los rangos de fechas definidos por las filas existentes en la tabla:

AND(
([End] > [Start]),
(COUNT(
FILTER(
"MyTable",
OR(
AND(
([Start] >= [_THISROW].[Start]),
([Start] <= [_THISROW].[End])
),
AND(
([End] >= [_THISROW].[Start]),
([End] <= [_THISROW].[End])
)
AND(
([Start] < [_THISROW].[Start]),
([End] > [_THISROW].[End])
)
)
)
) = 0)
)

1. AND(..., ...): ambas condiciones deben ser verdaderas.
2. ([End] > [Start]): la nueva fecha de finalización debe ser al menos un día posterior a la fecha de inicio.
3. (COUNT(...) = 0): el adjunto FILTER() no debe encontrar filas coincidentes; es decir, ningún rango de inicio/fin existente puede incluir el nuevo rango.
4. FILTER("MyTable", ...): busca filas en MyTable ese criterio de coincidencia.
5. OR(..., ..., ...): al menos una condición debe ser verdadera.
6. AND(..., ...): ambas condiciones deben ser verdaderas.
7. ([Start] >= [_THISROW].[Start]): la fecha de inicio existente ocurre en o después de la nueva fecha de inicio.
8. ([Start] <= [_THISROW].[End]): la fecha de inicio existente ocurre antes o en la nueva fecha de finalización.
9. AND(..., ...): ambas condiciones deben ser verdaderas.
10. ([End] >= [_THISROW].[Start]): la fecha de finalización existente se produce en o después de la nueva fecha de inicio.
11. ([End] <= [_THISROW].[End]): la fecha de finalización existente se produce antes o en la nueva fecha de finalización.
12. AND(..., ...): ambas condiciones deben ser verdaderas.
13. ([Start] < [_THISROW].[Start]): la fecha de inicio existente es anterior a la nueva fecha de inicio.
14. ([End] > [_THISROW].[End]): la fecha de finalización existente ocurre después de la nueva fecha de finalización

Si un rango de fechas existente comienza en (6-8), termina en (9-11) o encierra (12-14) el nuevo rango, el filtro selecciona la fila (5) y devuelve la lista de filas seleccionadas (4) . Una lista no vacía significa que al menos un intervalo de fechas existente se superpone al nuevo intervalo.
Si la fecha de finalización de la nueva fila es posterior a la fecha de inicio (2) y la lista de filas seleccionadas está vacía (3), la expresión es verdadera (1), lo que significa que la nueva fecha es válida y no entra en conflicto con ninguna fecha existente.

Sintaxis​

AND(condition1, condition2, [condition3 ...])

• condition - Una Yes/No expresión que resulte en TRUEo FALSE. Se requieren al menos dos conditionargumentos.

Fuente Google support